Высота растрового изображения в пикселах.

Прямоугольник, определяющий размер и расположение растрового изображения. Верхняя левая точка прямоугольника имеет значение 0; ширина и высота в пикселах равны размерам объекта BitmapData.

Определяет, поддерживает ли растровое изображение попиксельную прозрачность. Это значение можно задавать, только когда при создании объекта BitmapData в конструкторе передается значениеtrue для параметра transparent. Затем, когда объект BitmapData создан, можно узнать, поддерживает ли он попиксельную прозрачность: для этого нужно проверить, имеет ли свойство transparent значение true.

Ширина растрового изображения в пикселах.

Создает объект BitmapData заданной ширины и высоты. Если задать значение для параметра fillColor, каждый пиксел растрового изображения будет окрашен в этот цвет.

По умолчанию растровое изображение создается прозрачным, если не передано значение false для параметра transparent. Создав непрозрачное растровое изображение, его нельзя сделать прозрачным. Каждый пиксел непрозрачного растрового изображения использует только 24 бита информации о цветовых каналах. Если растровое изображение определено как прозрачное, каждый пиксел использует 32 бита информации о цветовых каналах, включая канал альфа-прозрачности.

Максимальная ширина и высота объекта BitmapData составляет 2880 пикселов. Если задать значение ширины или высоты, превышающее 2880, новый экземпляр не будет создан.

Создает фильтрованное изображение по исходному изображению и объекту filter.

Этот метод базируется на поведении встроенных объектов фильтра, которые определяют целевой прямоугольник, затрагиваемый вводным исходным прямоугольником.

Полученное после применения фильтра изображение может быть больше вводного. Например, если класс BlurFilter используется, чтобы размыть очертания исходного прямоугольника с координатами (50,50,100,100) и точку назначения с координатами (10,10), то область конечного изображения будет больше (10,10,60,60) в результате размытости. Это происходит на внутреннем уровне при вызове метода applyFilter().

Если параметр sourceRect параметра sourceBitmapData является внутренней областью, например (50,50,100,100) в изображении 200 x 200, фильтр использует исходные пикселы за пределами параметра sourceRect, чтобы создать целевой прямоугольник.

Если объект BitmapData является объектом, указанным в качестве параметра sourceBitmapData, проигрыватель Flash Player использует временную копию объекта для выполнения фильтрации. Если требуется обеспечить максимальную производительность, такую ситуацию лучше избегать.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();
bmd.applyFilter(bmd, rect, pt, filter);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Возвращает новый объект BitmapData, являющийся клоном исходного экземпляра с точной копией содержащегося в нем растрового изображения.

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(100, 80, false, 0x00000000);
var bmd2:BitmapData = bmd1.clone();

bmd1.setPixel32(1, 1, 0xFFFFFFFF);

trace(bmd1.getPixel32(1, 1).toString(16)); // ffffffff
trace(bmd2.getPixel32(1, 1).toString(16)); // ff000000

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);

var bm2:Bitmap = new Bitmap(bmd2);
bm2.x = 110;
this.addChild(bm2);

Изменяет значения цветов в заданной области растрового изображения с помощью объекта ColorTransform. Если прямоугольник соответствует границам растрового изображения, этот метод преобразует значения цветов для всего изображения.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.ColorTransform;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFF0000);

var cTransform:ColorTransform = new ColorTransform();
cTransform.alphaMultiplier = 0.5
var rect:Rectangle = new Rectangle(0, 0, 40, 30);
bmd.colorTransform(rect, cTransform);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Сравнивает два объекта BitmapData. Если два объекта BitmapData имеют одинаковые размеры (ширину и высоту), метод возвращает новый объект BitmapData, в котором каждый пиксел представляет "разницу" между пикселами двух исходных объектов.

• Если пикселы равны, то пиксел разницы будет иметь значение 0x00000000.
• Если у двух пикселов разные RGB-значения (игнорирующие значение альфа-канала), то пиксел разницы будет иметь значение 0xRRGGBB, где RR/GG/BB — это индивидуальные значения разницы между красными, зелеными и синими каналами (значение пиксела в исходном объекте минус значение пиксела в объекте otherBitmapData). В данном случае различия значений альфа-канала игнорируются.
• Если же альфа-канал имеет другое значение, то значением пиксела будет 0xZZFFFFFF, где ZZ — это разница между значениями альфа-канала (значение альфа-канала исходного объекта минус значение альфа-канала объекта otherBitmapData).

В качестве примера рассмотрим два следующих объекта BitmapData.

  var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFF8800);
  var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCCC6600);
  var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
  trace ("0x" + diffBmpData.getPixel(0,0).toString(16); // 0x332200
  

Примечание. Цвета, использованные для заливки двух объектов BitmapData, имеют немного разные RGB-значения (0xFF8800 и 0xCC6600). В результате использования метода compare() создается новый объект BitmapData, каждый пиксел которого показывает разницу RGB-значений между двумя растровыми изображениями.

Рассмотрим следующие два объекта BitmapData, у которых одинаковые RGB-цвета, но разные значения альфа-канала.

  var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
  var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
  var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
  trace ("0x" + diffBmpData.getPixel32(0,0).toString(16); // 0x33ffffff
  

В результате использования метода compare() создается новый объект BitmapData, каждый пиксел которого показывает разницу значений альфа-канала между двумя растровыми изображениями.

Если объекты BitmapData идентичны (имеют одинаковую высоту, ширину и значения пикселов), метод возвращает значение 0.

Если объекты BitmapData имеют разную ширину, метод возвращает значение -3.

Если объекты BitmapData имеют разную высоту, но одинаковую ширину, метод возвращает значение -4.

В следующем примере сравниваются два объекта Bitmap с разной шириной (50 и 60).

  var bmd1:BitmapData = new BitmapData(100, 50, false, 0xFFFF0000);
  var bmd2:BitmapData = new BitmapData(100, 60, false, 0xFFFFAA00);
  trace(bmd1.compare(bmd2)); // -4
  

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
var diffBmpData:BitmapData = BitmapData(bmd1.compare(bmd2));
var diffValue:String = diffBmpData.getPixel32(1, 1).toString(16);
trace (diffValue); // 33ffffff

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 60;

Переносит данные из одного канала отдельного объекта BitmapData или текущего объекта BitmapData в канал текущего объекта BitmapData. Все данные в других каналах конечного объекта BitmapData сохраняются.

Исходным или конечным значением канала может быть одно из следующих:

• BitmapDataChannel.RED
• BitmapDataChannel.GREEN
• BitmapDataChannel.BLUE
• BitmapDataChannel.ALPHA

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd.copyChannel(bmd, rect, pt, BitmapDataChannel.RED, BitmapDataChannel.BLUE);

var bm:Bitmap = new Bitmap(bmd);
this.addChild(bm);    

Представляет собой процедуру быстрой обработки точек изображений без растяжения, поворота и цветовых эффектов. Этот метод копирует прямоугольную область исходного изображения в прямоугольную область того же размера в точке назначения конченого объекта BitmapData.

Если включены параметры alphaBitmap и alphaPoint, можно использовать вторичное изображение в качестве источника альфа-канала для исходного изображения. Если исходное изображение имеет данные альфа-канала, то для переноса пикселов из исходного изображения в конечное используются оба набора данных альфа-канала. Параметр alphaPoint — это точка на альфа-изображении, соответствующая верхнему левому углу исходного прямоугольника. Все пикселы, не находящиеся в области пересечения исходного изображения и альфа-изображения, не копируются в конечное изображение.

Свойство mergeAlpha контролирует, используется или нет альфа-канал при копировании одного прозрачного изображения в другое прозрачное изображение. Чтобы копировать пикселы с данными альфа-канала, задайте свойству mergeAlpha значение true. По умолчанию свойство mergeAlpha имеет значение false.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(40, 40, false, 0x000000FF);
var bmd2:BitmapData = new BitmapData(80, 40, false, 0x0000CC44);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd2.copyPixels(bmd1, rect, pt);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 50;

Очищает память, задействованную для хранения объекта BitmapData.

Когда для изображения вызывается метод dispose(), его ширина и высота получают значение 0. Все последующие вызовы методов и свойств данного экземпляра BitmapData заканчиваются неудачно и приводят к появлению исключения.

import flash.display.BitmapData;

var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x000000FF);
trace(myBitmapData.getPixel(1, 1)); // 255 == 0xFF

myBitmapData.dispose();
try {
    trace(myBitmapData.getPixel(1, 1));
} catch (error:Error) {
    trace(error); // ArgumentError
}

Отображает исходный экранный объект source поверх растрового изображения с помощью векторного средства визуализации проигрывателя Flash Player. Можно задать параметры matrix, colorTransform, blendMode и clipRect назначения, чтобы управлять процессом визуализации. Также можно указать, должно ли смягчаться растровое изображение при масштабировании (это применимо только если источником является объект BitmapData).

Этот метод напрямую соответствует тому, как рисуются объекты с помощью стандартного векторного средства визуализации в интерфейсе инструмента разработки.

Исходный экранный объект не использует свои примененные преобразования для этого вызова. Он обрабатывается в том виде, в котором представлен в библиотеке или файле: без преобразования матрицы, цвета и без режима наложения. Чтобы нарисовать экранный объект (например, фрагмент ролика) с помощью его собственных свойств преобразования, можно скопировать его объект свойства transform в свойство transform объекта Bitmap, использующего объект BitmapData.

Примечание. Объект source и (в случае с объектами Sprite и MovieClip) все его дочерние объекты должны находиться в том же домене, что и вызывающий объект, или в SWF-файле, доступном вызывающему объекту посредством вызова метода Security.allowDomain(). Если эти условия не соблюдаются, метод draw() ничего не рисует.

Этот метод поддерживается через RTMP в Flash Player 9.0.115.0 и более поздних версий. Можно контролировать потоки на сервере Flash Media Server в сценарии, выполняемом на стороне сервера. Дополнительные сведения см. в разделах о свойствах Client.audioSampleAccess и Client.videoSampleAccess в документе Ссылка на языке ActionScript на стороне сервера для Adobe Flash Media Server.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.draw(tf);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Заполняет прямоугольную область пикселов заданным цветом ARGB.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x0000FF);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Выполняет операцию заливки изображения, начиная с точки с координатами (x, y) и заполняя область определенным цветом. Метод floodFill() напоминает инструмент "Ведро с краской" в различных программах для рисования. Цвет представляет собой цвет ARGB, содержащий информацию альфа-канала и данные цвета.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x000000FF);
rect = new Rectangle(15, 15, 25, 25);
myBitmapData.fillRect(rect, 0x000000FF);

myBitmapData.floodFill(10, 10, 0x00FF0000);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Определяет целевой прямоугольник, на который воздействует вызов метода applyFilter(), при наличии объекта BitmapData, исходного прямоугольника и объекта фильтра.

Например, размывающий фильтр обычно воздействует на область, размер которой превышает размер исходного изображения. Изображение размером 100 x 200 пикселов, отфильтрованное с использованием экземпляра BlurFilter по умолчанию, где blurX = blurY = 4 создает целевой прямоугольник с координатами (-2,-2,104,204). Метод generateFilterRect() позволяет заранее определять размер целевого прямоугольника, чтобы соответствующим образом изменить его размеры перед применением фильтра.

Некоторые фильтры обрезают целевой прямоугольник по размеру исходного изображения. Например, внутренний фильтр DropShadow не увеличивает размер по сравнению с исходным изображением. В данном API-интерфейсе объект BitmapData используется в качестве исходных границ, а не исходного параметра rect.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();

trace(bmd.generateFilterRect(rect, filter));
// (x=8, y=8, w=44, h=14)

bmd.applyFilter(bmd, rect, pt, filter);
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Определяет прямоугольный участок, полностью охватывающий все пикселы заданного цвета в пределах растрового изображения (если параметру findColor присвоено значение true), либо полностью охватывает все пикселы, не содержащие заданный цвет (если параметру findColor присвоено значение false).

Например, если имеется исходное изображение и требуется определить прямоугольник изображения, содержащий ненулевой альфа-канал, передайте в качестве параметров {mask: 0xFF000000, color: 0x00000000}. Если параметру findColor задано значение true, в пределах всего изображения ведется поиск границ с пикселами, для которых (value & mask) == color (где value — это значение цвета пиксела). Если параметру findColor задано значение false, в пределах всего изображения ведется поиск границ пикселов, для которых (value & mask)!= color (где value — это значение цвета пиксела). Чтобы определить белое пространство вокруг изображения, передайте {mask: 0xFFFFFFFF, color: 0xFFFFFFFF}, чтобы найти границы небелых пикселов.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFFFFFF);
var rect:Rectangle = new Rectangle(0, 0, 80, 20);
bmd.fillRect(rect, 0xFF0000);

var maskColor:uint = 0xFFFFFF; 
var color:uint = 0xFF0000;  
var redBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, true);
trace(redBounds); // (x=0, y=0, w=80, h=20)

var notRedBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, false);
trace(notRedBounds); // (x=0, y=20, w=80, h=20)

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Возвращает целое число, представляющее RGB-значение пиксела из объекта BitmapData в конкретной точке (x, y). Метод getPixel() возвращает неумноженное значение пиксела. Информация альфа-канала не возвращается.

Все пикселы в объекте BitmapData сохраняются как предварительно умноженные значения цвета. В предварительно умноженном пикселе изображения значения красного, зеленого и синего канала уже умножены на данные альфа-канала. Например, если значение альфа-канала равно нулю, то значения RGB-каналов также равны нулю независимо от их значений до умножения. Потеря данных может вызвать проблемы при выполнении операций. Все методы BitmapData принимают и возвращают неумноженные значения. Перед тем как возвращать значение, внутреннее представление пиксела преобразуется из предварительно умноженного в неумноженное. Во время операции настройки, значение пиксела предварительно умножается, и только после этого настраивается необработанный пиксел изображения.

Параметры

См. также

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFF0000);

var pixelValue:uint = bmd.getPixel(1, 1);
trace(pixelValue.toString(16)); // ff0000;

Возвращает значение цвета ARGB, содержащее данные альфа-канала и данные RGB. Этот метод подобен методу getPixel(), который возвращает RGB-цвет без данных альфа-канала.

Все пикселы в объекте BitmapData сохраняются как предварительно умноженные значения цвета. В предварительно умноженном пикселе изображения значения красного, зеленого и синего канала уже умножены на данные альфа-канала. Например, если значение альфа-канала равно нулю, то значения RGB-каналов также равны нулю независимо от их значений до умножения. Потеря данных может вызвать проблемы при выполнении операций. Все методы BitmapData принимают и возвращают неумноженные значения. Перед тем как возвращать значение, внутреннее представление пиксела преобразуется из предварительно умноженного в неумноженное. Во время операции настройки, значение пиксела предварительно умножается, и только после этого настраивается необработанный пиксел изображения.

Параметры

См. также

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, true, 0xFF44AACC);

var pixelValue:uint = bmd.getPixel32(1, 1);
var alphaValue:uint = pixelValue >> 24 & 0xFF;
var red:uint = pixelValue >> 16 & 0xFF;
var green:uint = pixelValue >> 8 & 0xFF;
var blue:uint = pixelValue & 0xFF;

trace(alphaValue.toString(16)); // ff
trace(red.toString(16)); // 44
trace(green.toString(16)); // aa
trace(blue.toString(16)); // cc

Формирует байтовый массив из прямоугольного участка пиксельных данных. Записывает неподписанное целое число (32-разрядное неумноженное значение пиксела) для каждого пиксела в байтовом массиве.

Параметры

См. также

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

var bmd:BitmapData = new BitmapData(80, 40, true);
var seed:int = int(Math.random() * int.MAX_VALUE);
bmd.noise(seed);

var bounds:Rectangle = new Rectangle(0, 0, bmd.width, bmd.height);
var pixels:ByteArray = bmd.getPixels(bounds);

DOCUMENT ME

Параметры

Вычисляет гистограмму на 256 секций для объекта BitmapData. Функция возвращает вектор из четырех численных векторов. Эти четыре численных вектора представляют красный, зеленый, синий и альфа-компоненты соответственно. Каждый численный вектор содержит 256 значений, представляющих счетчик заполнения значения отдельного компонента, от 0 до 255.

Параметры

Выполняет распознавание на уровне пикселов между одним растровым изображением и точкой, прямоугольником или другим растровым изображением. Попаданием считается наложение точки или прямоугольника на непрозрачный пиксел или два накладывающихся непрозрачных пиксела. При тестировании нажатия растягивание, поворот и другие преобразования обоих объектов не учитываются.

Если изображение непрозрачное, то при использовании данного метода оно считается полностью непрозрачным прямоугольником. Для тестирования нажатия, при котором учитывается прозрачность, оба изображения должны быть прозрачными. Когда тестируются два прозрачных изображения, параметры порога значений альфа-канала контролируют, какие значения альфа-канала (от 0 до 255) считаются непрозрачными.

Параметры

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(80, 80, true, 0x00000000);
var rect:Rectangle = new Rectangle(20, 20, 40, 40);
bmd1.fillRect(rect, 0xFF0000FF);

var pt1:Point = new Point(1, 1);
trace(bmd1.hitTest(pt1, 0xFF, pt1)); // false
var pt2:Point = new Point(40, 40);
trace(bmd1.hitTest(pt1, 0xFF, pt2)); // true

Блокирует изображение, чтобы любые объекты, ссылающиеся на объект BitmapData, например объекты Bitmap, не обновлялись при изменении данного объекта BitmapData. Чтобы повысить производительность, используйте этот метод вместе с методом unlock() до или после многочисленных вызовов метода setPixel() или setPixel32().

См. также

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

Проводит наложение каналов исходного изображения на целевое изображение. Для каждого канала и каждого пиксела вычисляется новое значение на основе значений каналов исходных и целевых пикселов. Например, в красном канале новое значение вычисляется следующим образом (где redSrc — это значение красного канала для пиксела в исходном изображении, а redDest — это значение красного канала в соответствующем пикселе целевого изображения):

new redDest = [(redSrc * redMultiplier) + (redDest * (256 - redMultiplier))] / 256;

Значения redMultiplier, greenMultiplier, blueMultiplier и alphaMultiplier являются множителями, используемыми для канала каждого цвета. Используйте шестнадцатеричное значение от 0 до 0x100 (256), где 0 обозначает, что в результате используется полное значение целевого изображения, а 0x100 — что используется полное значение исходного изображения, а промежуточные числа означают, что используется наложение (так 0x80 указывает на 50-процентное наложение).

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(100, 80, true, 0xFF00FF00);
var bmd2:BitmapData = new BitmapData(100, 80, true, 0xFFFF0000);
var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(20, 20);
var mult:uint = 0x80; // 50% 
bmd1.merge(bmd2, rect, pt, mult, mult, mult, mult);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Заполняет изображение пикселами, представляющими собой белый шум.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;

var bmd1:BitmapData = new BitmapData(80, 80);
var bmd2:BitmapData = new BitmapData(80, 80);

var seed:int = int(Math.random() * int.MAX_VALUE);
bmd1.noise(seed, 0, 0xFF, BitmapDataChannel.RED, false);
bmd2.noise(seed, 0, 0xFF, BitmapDataChannel.RED, true);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 90;

Переназначает значения цветовых каналов в изображении, содержащем до четырех массивов данных цветовой палитры, по одному для каждого канала.

Проигрыватель Flash Player выполняет следующие шаги для создания конечного изображения:

1. После вычисления значения красного, зеленого, синего и альфа-каналов складываются, образуя стандартное 32-разрядное целое число.
2. Значения красного, зеленого, синего и альфа-каналов каждого пиксела извлекаются в отдельные значения от 0 до 255. Эти значения используются для поиска новых значений цвета в соответствующем массиве: redArray, greenArray, blueArray и alphaArray. Каждый из этих четырех массивов должен содержать 256 значений.
3. После получения новых значений для всех четырех каналов, они образуют стандартное значение ARGB, которое применяется к пикселу.

Этот метод может поддерживать эффекты, создаваемые с использованием разных каналов. Каждый вводный массив содержит полные 32-разрядные значения, поэтому при складывании значений не происходит смещения. Эта подпрограмма не поддерживает фиксацию по каналам.

Если для канала не задан массив, то канал цвета копируется из исходного изображения в целевое.

Этот метод можно использовать для самых разнообразных эффектов, таких как общее наложение палитры (преобразование одного канала для создания псевдо-цветного изображения). Этот метод можно использовать для различных расширенных алгоритмов манипуляций с цветом, таких как использование гаммы, кривых, уровней и квантизации.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var myBitmapData:BitmapData = new BitmapData(80, 80, false, 0x00FF0000);
myBitmapData.fillRect(new Rectangle(20, 20, 40, 40), 0x0000FF00);

var redArray:Array = new Array(256);
var greenArray:Array = new Array(256);

for(var i:uint = 0; i < 255; i++) {
    redArray[i] = 0x00000000;
    greenArray[i] = 0x00000000;
}

redArray[0xFF] = 0x0000FF00;
greenArray[0xFF] = 0x00FF0000;

var bottomHalf:Rectangle = new Rectangle(0, 0, 100, 40);
var pt:Point = new Point(0, 0);
myBitmapData.paletteMap(myBitmapData, bottomHalf, pt, redArray, greenArray);

var bm1:Bitmap = new Bitmap(myBitmapData);
addChild(bm1);

Создает изображение с шумом Перлина.

Алгоритм создания шума Перлина интерполирует и объединяет отдельные функции случайного шума (называемые октавами) в одну функцию, создающую более естественный случайный шум. Как и в музыкальных октавах, каждая функция октавы удваивает частоту предыдущей. Шум Перлина описывается как "фрактальная сумма шума", так как он объединяет несколько наборов шумовых данных с разным уровнем детализации.

Функции шума Перлина можно использовать для симуляции естественных явлений и ландшафтов, таких как текстура древесины, облака и горные хребты. В большинстве случаев результат функции шума Перлина не отображается непосредственно: он используется для доработки других изображений, придавая им псевдослучайные вариации.

Простые функции цифрового белого шума часто дают изображения с резко контрастирующими точками. Такое явление редко встречается в естественных условиях. Алгоритм шума Перлина объединяет несколько функций шума с разным уровнем детализации. В результате чего разница между значениями соседних пикселов становится не столь большой.

Примечание. Алгоритм шума Перлина назван в честь Кена Перлина, который создал его, работая над компьютерной графикой для фильма Tron в 1982 году. В 1997 году Перлин получил премию Американской академии киноискусств за технические достижения.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(200, 200, false, 0x00CCCCCC);

var seed:Number = Math.floor(Math.random() * 10);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd.perlinNoise(100, 80, 6, seed, false, true, channels, false, null);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Выполняет растворение точек от исходного изображения до целевого или для одного изображения. Проигрыватель Flash Player использует значение randomSeed для выполнения случайного растворения точек. Возвращаемое значение функции должно передаваться при последующих вызовах для продолжения растворения точек вплоть до завершения операции.

Если исходное изображение отличается от целевого, пикселы копируются из первого во второе с использованием всех свойств. Этот процесс позволяет выполнить растворение от пустого изображения до заполненного.

Если исходное и целевое изображения одинаковы, пикселы заполняются с помощью параметра color. Этот процесс позволяет выполнить растворение из заполненного изображения. В данном режиме целевой параметр point игнорируется.

Параметры

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.utils.Timer;
import flash.events.TimerEvent;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);
var bitmap:Bitmap = new Bitmap(bmd);
addChild(bitmap);

var tim:Timer = new Timer(20);
tim.start();
tim.addEventListener(TimerEvent.TIMER, timerHandler);
 
function timerHandler(event:TimerEvent):void {
    var randomNum:Number = Math.floor(Math.random() * int.MAX_VALUE);
    dissolve(randomNum);
}

function dissolve(randomNum:Number):void {
    var rect:Rectangle = bmd.rect;
    var pt:Point = new Point(0, 0);
    var numberOfPixels:uint = 100;
    var red:uint = 0x00FF0000;
    bmd.pixelDissolve(bmd, rect, pt, randomNum, numberOfPixels, red);
    var grayRegion:Rectangle = bmd.getColorBoundsRect(0xFFFFFFFF, 0x00CCCCCC, true);
    if(grayRegion.width == 0 && grayRegion.height == 0 ) {
        tim.stop();
    }
}

Прокручивает изображение на заданное число точек (x, y). Края за пределами области прокрутки остаются без изменений.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);
var rect:Rectangle = new Rectangle(0, 0, 40, 40);
bmd.fillRect(rect, 0xFFFF0000);
            
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

trace (bmd.getPixel32(50, 20).toString(16)); // ffcccccccc

bmd.scroll(30, 0); 

trace (bmd.getPixel32(50, 20).toString(16)); // ffff0000

Задает одиночный пиксел объекта BitmapData. При выполнении этой операции сохраняется текущее значение альфа-канала пиксела изображения. Значение параметра RGB-цвета обрабатывается как неумноженное значение цвета.

Примечание. Для повышения производительности при многократном использовании метода setPixel() или setPixel32() вызовите метод lock() перед тем, как вызывать setPixel() или setPixel32(), а по завершении внесения изменений в пикселы, вызовите метод unlock(). Эта процедура не позволяет объектам, ссылающимся на данный экземпляр BitmapData, обновляться, пока не будет завершено изменение пикселов.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, false, 0xCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0xFF0000;
    bmd.setPixel(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Задает значения цвета и альфа-прозрачности отдельно взятой точки объекта BitmapData. Этот метод поход на метод setPixel(). Основное различие заключается в том, что метод setPixel32() принимает ARGB-значение цвета, содержащее информацию об альфа-канале.

Все пикселы в объекте BitmapData сохраняются как предварительно умноженные значения цвета. В предварительно умноженном пикселе изображения значения красного, зеленого и синего канала уже умножены на данные альфа-канала. Например, если значение альфа-канала равно нулю, то значения RGB-каналов также равны нулю независимо от их значений до умножения. Потеря данных может вызвать проблемы при выполнении операций. Все методы BitmapData принимают и возвращают неумноженные значения. Перед тем как возвращать значение, внутреннее представление пиксела преобразуется из предварительно умноженного в неумноженное. Во время операции настройки, значение пиксела предварительно умножается, и только после этого настраивается необработанный пиксел изображения.

Примечание. Для повышения производительности при многократном использовании метода setPixel() или setPixel32() вызовите метод lock() перед тем, как вызывать setPixel() или setPixel32(), а по завершении внесения изменений в пикселы, вызовите метод unlock(). Эта процедура не позволяет объектам, ссылающимся на данный экземпляр BitmapData, обновляться, пока не будет завершено изменение пикселов.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0x60FF0000;
    bmd.setPixel32(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Преобразует массив байт в прямоугольный участок пиксельных данных. Для каждого пиксела вызывается метод ByteArray.readUnsignedInt() и записывается возвращаемое значение. Если массив байт заканчивается, прежде чем будет заполнен весь прямоугольник, функция возвращает исключение. Массив байт должен содержать 32-разрядные ARGB-значения пикселов. Перед считыванием пикселов и после него поиск по массиву байт не выполняется.

Параметры

См. также

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.utils.ByteArray;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(100, 100, true, 0xFFCCCCCC);
var bmd2:BitmapData = new BitmapData(100, 100, true, 0xFFFF0000);

var rect:Rectangle = new Rectangle(0, 0, 100, 100);
var bytes:ByteArray = bmd1.getPixels(rect);

bytes.position = 0;
bmd2.setPixels(rect, bytes);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Параметры

Сопоставляет пиксельные значения в изображении с заданным пороговым значением и присваивает пикселам, прошедшим проверку, новые цветовые значения. С помощью метода threshold() можно изолировать и заменить диапазоны в изображении и выполнить другие логические операции над его пикселами.

Проверка метода threshold() имеет следующую логику:

1. если ((pixelValue & mask) operation (threshold & mask)), то установите color для пиксела;
2. В противном случае, если copySource == true, то пиксел получает соответствующее значение из sourceBitmap.

Параметр operation задает оператор сравнения, используемый при пороговой проверке. Например, используя "==" в качестве параметра operation можно изолировать конкретное цветовое значение в изображении. А с помощью операции {operation: "<", mask: 0xFF000000, threshold: 0x7F000000, color: 0x00000000} можно сделать все целевые пикселы полностью прозрачными, если значение альфа-канала пиксела исходного изображения меньше 0x7F. Этот прием можно использовать для анимированных переходов и других эффектов.

Параметры

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.geom.Point;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);

var seed:int = int(Math.random() * int.MAX_VALUE);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd1.perlinNoise(100, 80, 12, seed, false, true, channels, false, null);

var bitmap1:Bitmap = new Bitmap(bmd1);
addChild(bitmap1);

var bmd2:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);
var pt:Point = new Point(0, 0);
var rect:Rectangle = new Rectangle(0, 0, 200, 200);
var threshold:uint =  0x00800000; 
var color:uint = 0x20FF0000;
var maskColor:uint = 0x00FF0000;
bmd2.threshold(bmd1, rect, pt, ">", threshold, color, maskColor, true);

var bitmap2:Bitmap = new Bitmap(bmd2);
bitmap2.x = bitmap1.x + bitmap1.width + 10;
addChild(bitmap2);

Разблокирует изображение, чтобы любые объекты, ссылающиеся на объект BitmapData, например объекты Bitmap, обновлялись при изменении данного объекта BitmapData. Чтобы повысить производительность, используйте этот метод вместе с методом lock() до или после многочисленных вызовов метода setPixel() или setPixel32().

Параметры

См. также

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

1. Создается свойство url, описывающее местоположение и имя файла изображения.
2. Конструктор класса создает объект Loader, который затем создает экземпляр прослушивателя событий, отправляемых по завершении обработки изображения методом completeHandler().
3. Затем объект URLRequest с именем request передается методу loader.load(), который загружает изображение в память с помощью экранного объекта.
4. После этого изображение добавляется в список отображения, который показывает изображение на экране в положении с координатами x = 0, y = 0.
5. Затем метод completeHandler() выполняет следующее:
   • Создает второй объект Loader и инициализированный вместе с ним объект Bitmap.
   • Создает второй объект Bitmap, duplicate, который в свою очередь вызывает метод duplicateImage(), создающий дубликат исходного изображения.
   • Создает объект BitmapData, который назначается объекту BitmapData объекта duplicate.
   • Создает новый объект Rectangle, инициализированный с теми же координатами, шириной и высотой, что и исходное изображение.
   • Создает новый объект Point с координатами по умолчанию: x = 0, y = 0.
   • Создает следующие переменные:
     • operation — применяет новый цвет, когда пороговое значение больше или равно исходному.
     • threshold — значение, с которым сравнивается каждый пиксел (в данном примере это светло-серый цвет со значением альфа-канала 0xCC).
     • color — цвет, который будет задан пикселам, проходящим пороговый тест, — в данном случае это сплошной желтый цвет.
     • mask — диаметрально противоположный цвет (прозрачный синий).
     • copySource — получает значение false, указывающее на то, что значения пикселов не копируются в том случае, если пороговое значение не проходит. Это значение не имеет смысла, потому что изображение продублировано и изменяются только пикселы, прошедшие пороговый тест.
   • Вызывает метод threshold() с использованием предшествующих переменных. В результате мы получаем уравнение порога: если (текущее значение пиксела & 0x000000FF) больше или равно (0xCCCCCCCC & 0x000000FF), то ему задается 0xFFFFFF00.

Примечания.

• SWF-файл потребуется откомпилировать с установленным для параметра "Безопасность локального воспроизведения" режимом "Доступ только к локальным файлам".
• Данный пример требует, чтобы файл с именем Image.gif находился в том же каталоге, что и SWF-файл.
• Рекомендуется использовать изображение с шириной не больше 80 пикселов.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapDataExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapDataExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}