Значение альфа-прозрачности для цвета тени. Действительны значения от 0,0 до 1,0. Например, значение 0,25 задает 25-процентную прозрачность. Значение по умолчанию 1.0.

Угол тени. Действительны значения от 0 до 360 градусов (плавающая точка). Значение по умолчанию 45.

Степень размытия по горизонтали. Действительны значения от 0 до 255 (плавающая точка). Значение по умолчанию 4.0.

Степень размытия по вертикали. Действительны значения от 0 до 255 (плавающая точка). Значение по умолчанию 4.0.

Цвет тени. Действительны значения в шестнадцатеричном формате 0xRRGGBB. Значение по умолчанию — 0x000000.

Расстояние смещения для тени (в пикселах). Значение по умолчанию — 4,0 (плавающая точка).

Определяет, является ли объект скрытым. Значение true указывает на то, что сам объект не нарисован, видна только его день. Значение по умолчанию — false (объект отображается).

Определяет, является ли тень внутренней тенью. Значение true указывает на наличие внутренней тени. Значение по умолчанию false задает внешнюю тень (тень вокруг внешнего контура объекта).

Применяет эффект выбивки (true), который фактически делает заливку объекта прозрачной и выявляет цвет фона документа. Значение по умолчанию — false (без выбивки).

Заданное число применений фильтра. Значение по умолчанию — BitmapFilterQuality.LOW, что эквивалентно однократному применению фильтра. Значение BitmapFilterQuality.MEDIUM применяет фильтр дважды; значение BitmapFilterQuality.HIGH — трижды. Фильтры с более низкими значениями выполняются быстрее.

Для большинства приложений достаточно значений качества "low" ("низкое"), "medium" ("среднее") или "high" ("высокое"). Хотя можно использовать дополнительные числовые значения до 15 для получения разнообразных эффектов, более высокие значения выполняются дольше. Вместо увеличения значения quality можно просто увеличить значения свойств blurX и blurY. Это даст похожий эффект, а выполнение будет происходить быстрее.

См. также

Степень вдавливания или растискивания. Чем выше значение, тем более насыщен цвет тени и тем сильнее контраст между тенью и фоном. Действительны значения от 0 до 255,0. Значение по умолчанию — 1,0.

Инициализирует новый экземпляр DropShadowFilter с заданными параметрами.

См. также

Возвращает копию данного объекта фильтра.

1. Задаются три свойства, которые используются для отрисовки квадрата, к которому применяется фильтр.
2. Создается функция конструктора. Конструктор вызывает метод draw(), использующий методы класса Graphics, полученные через свойство graphics спрайта для рисования оранжевого квадрата.
3. В конструкторе задается переменная filter в виде объекта BitmapFilter и назначается возвращаемому значению вызова метода getBitmapFilter(). Метод getBitmapFilter() определяет используемый фильтр теней.
4. Создается новый объект массива myFilters, и к массиву добавляется фильтр filter. Массив myFilters назначается свойству filtersобъекта DropShadowFilterExample. В результате применяются все фильтры, обнаруженные в myFilters. В нашем случае это только один фильтр filter.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.DropShadowFilter;

    public class DropShadowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function DropShadowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x000000;
            var angle:Number = 45;
            var alpha:Number = 0.8;
            var blurX:Number = 8;
            var blurY:Number = 8;
            var distance:Number = 15;
            var strength:Number = 0.65;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;
            return new DropShadowFilter(distance,
                                        angle,
                                        color,
                                        alpha,
                                        blurX,
                                        blurY,
                                        strength,
                                        quality,
                                        inner,
                                        knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}