Степень размытия по горизонтали. Действительны значения от 0 до 255 (плавающая точка). Значение по умолчанию 4. Значения, являющиеся степенью 2 (т.е. 2, 4, 8, 16 и 32), оптимизируются и выполняются быстрее, чем остальные.

Степень размытия по вертикали. Действительны значения от 0 до 255 (плавающая точка). Значение по умолчанию 4. Значения, являющиеся степенью 2 (т.е. 2, 4, 8, 16 и 32), оптимизируются и выполняются быстрее, чем остальные.

Число применений эффекта "Размытие". Значение по умолчанию — BitmapFilterQuality.LOW, что эквивалентно однократному применению фильтра. Значение BitmapFilterQuality.MEDIUM применяет фильтр дважды; значение BitmapFilterQuality.HIGH — трижды для получения размытия по Гауссу. Фильтры с более низкими значениями выполняются быстрее.

Для большинства приложений достаточно значения quality на уровне "low" ("низкое"), "medium" ("среднее") или "high" (высокое). Хотя можно использовать дополнительные числовые значения до 15 для увеличения числа раз применения эффекта размытия, более высокие значения выполняются дольше. Вместо увеличения значения quality можно просто увеличить значения свойств blurX и blurY. Это даст похожий эффект, а выполнение будет происходить быстрее.

Можно использовать следующие константы BitmapFilterQuality для задания свойства quality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Инициализирует фильтр с заданными параметрами. Значения по умолчанию дают мягкое, расфокусированное изображение.

Возвращает копию данного объекта фильтра.

1. Импортируется требуемый класс.
2. Объявляются три свойства функции draw(), рисующей объект, к которому и применяется фильтр "Размытие".
3. Создается функция конструктора BlurFilterExample(), которая выполняет следующее:
   • Вызывает функцию draw(), которая объявляется позднее.
   • Объявляет переменную filter в виде объекта BitmapFilter и назначает ее возвращаемому значению вызова getBitmapFilter().
   • Создает новый массив myFilters и добавляет к массиву filter, а также назначает myFilters свойству filters объекта BlurFilterExample. В результате применяются все фильтры, обнаруженные в myFilters. В нашем случае это только один фильтр filter.
4. Создайте функцию getBitmapFilter для создания фильтра и задания его свойств.
5. Создайте функцию draw(). Эта функция использует методы класса Graphics, доступные через свойство graphics класса Sprite для рисования квадрата.

package {
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BlurFilter;

    public class BlurFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BlurFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var blurX:Number = 30;
            var blurY:Number = 30;
            return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}