Значение класса StageAlign, задающее выравнивание рабочей области в проигрывателе Flash Player или обозревателе. Ниже приводятся допустимые значения.

Свойство align доступно только для объекта, находящегося в той же изолированной программной среде безопасности, что и владелец объекта Stage (главный SWF-файл). Во избежание этого владелец объекта Stage может предоставить разрешение домену вызывающего объекта путем вызова метода Security.allowDomain() или метода Security.allowInsecureDomain(). Дополнительные сведения см. в главе "Безопасность" в книге Программирование на ActionScript 3.0.

См. также

Значение класса StageDisplayState, задающее состояние отображения. Ниже приводятся допустимые значения.

• StageDisplayState.FULL_SCREEN предписывает приложению AIR развернуть рабочую область на весь экран пользователя, отключив ввод с клавиатуры.
• StageDisplayState.FULL_SCREEN_INTERACTIVE предписывает приложению AIR развернуть рабочую область на весь экран пользователя, не отключая ввод с клавиатуры. (Недоступно для содержимого, выполняемого в Flash Player.)
• StageDisplayState.NORMAL возвращает проигрыватель в стандартный режим отображения рабочей области.

Масштабирование видео в полноэкранном режиме определяется значением scaleMode (которое задается при помощи свойства Stage.scaleMode параметрами тегов embed SWF-файла в файле HTML). Если для свойства scaleMode задано значение noScale при переходе приложения в полноэкранный режим, свойства объекта Stage width и height обновляются, и объект Stage получает событие resize.

Следующие ограничения действуют для SWF-файлов, проигрываемых на странице HTML (не для тех, что выполняются в автономном проигрывателе Flash Player и не выполняются в среде AIR):

• Для включения полноэкранного режима добавьте параметр allowFullScreen в теги object и embed страницы HTML, содержащей SWF-файл, задав для свойства allowFullScreen значение "true", как показано в следующем примере:

  <param name="allowFullScreen" value="true" />
           ...
    <embed src="example.swf" allowFullScreen="true" ... >

  Страница HTML может также выполнить сценарий для создания тегов внедрения SWF. Такой сценарий нужно изменить, задав нужные значения для свойства allowFullScreen. Страницы HTML, созданные при помощи Flash и Flex Builder, используют функцию AC_FL_RunContent() для вставки ссылок на SWF-файлы, поэтому необходимо добавить значения параметра allowFullScreen, как в следующем примере:

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• Полноэкранный режим запускается в ответ на щелчок мышью или нажатие кнопки пользователем; значение свойства Stage.displayState не может измениться без ввода пользователя. При работе Flash Player в полноэкранном режиме ввод с клавиатуры отключен (за исключением клавиш быстрого вызова, при помощи которых пользователь может выйти из полноэкранного режима). При переходе в полноэкранный режим поверх видео отображается диалоговое окно Flash Player, уведомляющее пользователей о том, что включен полноэкранный режим и можно нажать клавишу Escape для выхода из этого режима.
• Начиная с Flash Player 9.0.115.0, полноэкранный режим работает одинаково в безоконном и оконном режиме. Если вы установите "Режим окна" (wmode в HTML) на "Непрозрачный, без окна" (opaque) или "Прозрачный, без окна" (transparent), полноэкранный режим может быть включен, но окно всегда будет непрозрачным.

Данные ограничения не действуют для содержимого SWF, выполняемого в автономном Flash Player или в приложении AIR. AIR поддерживает интерактивный полноэкранный режим, который допускает ввод с клавиатуры.

На время воспроизведения ролика AIR в полноэкранном режиме экранная заставка ОС и управление питанием отключаются и становятся активными только при выходе из полноэкранного режима или завершении воспроизведения ролика.

См. также

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

Позволяет проигрывателю Flash Player отображать коррекцию цвета, соответствующую цветовому профилю ICC (International Color Consortium) главного (основного) монитора. Коррекция цвета срабатывает, только если главному монитору назначен действительный профиль ICC, задающий конкретные цветовые атрибуты устройства.

Используйте свойство flash.system.capabilities.hasColorCorrection, чтобы определить, доступна ли коррекция цвета в текущей системе. Если коррекция цвета доступна, все цвета в рабочей области должны находиться в пространстве цветов sRGB, которое на данный момент является наиболее распространенным. Во время цветовой коррекции исходные профили устройств ввода игнорируются. Коррекция цветов на вводе не применяется. На цветовой профиль IIC главного монитора накладывается только вывод рабочей области.

Обычно, активация управления цветом делает передачу цвета более точной, улучшает преобразование, позволяет точнее осуществлять цветопробу и эффективно отображать цвета независимо от программного материала. Имейте ввиду, что управление цветом не делает преобразование идеальным, так как цветовые гаммы различных устройств расходятся между собой и отличаются от палитр исходных изображений. Подобным образом, при использовании управления цветом не исключается необходимость использовать пользовательские или измененные профили. Профили цветов зависят от обозревателей, операционных систем (ОС), расширений ОС, устройств вывода и поддержки со стороны приложения.

При применении коррекции цвета производительность Flash Player снижается. В Flash Player коррекция цвета реализована в качестве документа стиля коррекции цвета, так как все ролики SWF являются документами со встроенными профилями sRGB. Используйте свойство enableColorCorrection, чтобы во время отображения документа SWF проигрыватель Flash Player осуществлял процесс коррекции цвета. Flash Player может компенсировать различия между мониторами, но не устройствами ввода (видеотехникой/сканнером и так далее).

См. также

Интерактивный объект с фокусом клавиатуры, либо null, если фокус не установлен, а также если объект с фокусом принадлежит к изолированной программной среде безопасности, доступ к которой отсутствует у вызывающего объекта.

Определяет и задает частоту кадров рабочей области. Частота кадров определяется как число кадров в секунду. По умолчанию используется значение частоты кадров первого загруженного SWF-файла. Допустимые значения частоты кадров находятся в диапазоне 0,01 — 1000 кадров в секунду.

Примечание. Приложение может не воспринимать параметры высокой частоты, если целевая платформа недостаточно быстрая или если проигрыватель синхронизируется с интервалами пробела по вертикали дисплея (обычно это 60 Гц на ЖК-мониторах). В некоторых случаях целевая платформа также может выбирать более низкую максимальную частоту кадров, если ожидает высокий процент использования ЦП.

При работе с содержимым в Adobe AIR настройка свойства frameRate одного объекта Stage приводит к изменению частоты кадров всех объектов Stage (используемых разными объектами NativeWindow).

Возвращает ту высоту монитора, которая будет использована при мгновенном переходе в полноэкранный режим. Если в системе установлено несколько мониторов, то используется тот из них, на котором в данный момент отображается большая часть рабочей области.

Примечание. Если у пользователя есть возможность перемещать обозреватель с одного монитора на другой между получением значения и переходом в полноэкранный режим, то это значение будет неправильным. Если значение получено в обработчике событий, задающем для Stage.displayState значение StageDisplayState.FULL_SCREEN, то значение будет правильным.

Это высота монитора в пикселах, она равна высоте рабочей области, если Stage.align для задано значение StageAlign.TOP_LEFT, а для Stage.scaleMode — StageScaleMode.NO_SCALE.

См. также

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

Flash Player масштабирует конкретный участок рабочей области в полноэкранный режим. Если есть возможность, проигрыватель Flash Player выполняет масштабирование с использованием аппаратных средств, включая графическую карту и видеокарту на компьютере пользователя. В этом случае отображение содержания, как правило, начинается намного быстрее, чем при масштабирование с помощью программных средств.

Когда этому свойству задано значение допустимого прямоугольника, а свойство displayState настроено на полноэкранный режим, проигрыватель Flash Player масштабирует заданную область. Фактический размер рабочей области в пикселах в ActionScript не изменяется. Проигрыватель Flash Player использует ограничение минимального размера прямоугольника, чтобы показать сообщение "Нажмите "Esc" для выхода из полноэкранного режима". Обычно минимальный размер бывает около 260 на 30 пикселов, но он может варьироваться в зависимости от платформы и версии Flash Player.

Это свойство можно настраивать, только когда проигрыватель не находится в полноэкранном режиме. Для правильного использования этого свойства его необходимо настроить первым, и только потом выбирать для свойства displayState полноэкранный режим, как показано в примерах кода.

Чтобы включить масштабирование, задайте свойство fullScreenSourceRect объекту прямоугольника.

  
  // valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
  

Чтобы отключить масштабирование, задайте fullScreenSourceRect=null в ActionScript 3.0 и undefined в ActionScript 2.0.

  stage.fullScreenSourceRect = null;
  

Конечный пользователь может отключить в параметрах отображения проигрывателя Flash Player аппаратное масштабирование, включенное по умолчанию. Дополнительные сведения см. на странице www.adobe.com/go/display_settings_ru.

См. также

 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

Возвращает ту ширину монитора, которая будет использована при мгновенном переходе в полноэкранный режим. Если в системе установлено несколько мониторов, то используется тот из них, на котором в данный момент отображается большая часть рабочей области.

Примечание. Если у пользователя есть возможность перемещать обозреватель с одного монитора на другой между получением значения и переходом в полноэкранный режим, то это значение будет неправильным. Если значение получено в обработчике событий, задающем для Stage.displayState значение StageDisplayState.FULL_SCREEN, то значение будет правильным.

Это ширина монитора в пикселах, она равна ширине рабочей области, если Stage.align для задано значение StageAlign.TOP_LEFT, а для Stage.scaleMode — StageScaleMode.NO_SCALE.

См. также

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

Указывает высоту экранного объекта в пикселах. Высота вычисляется на основе границ содержимого экранного объекта. Когда задается свойство height, соответствующим образом изменяется и свойство scaleY, как показано в следующем коде.

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleY) // 1;
    rect.height = 200;
    trace(rect.scaleY) // 2;

За исключением объектов TextField и Video, экранные объекты без содержимого (например, пустой спрайт), имеют высоту 0, даже если задать свойству height другое значение.

Определяет, включен ли переход между потомками объекта с помощью мыши. Если объект реагирует на мышь, пользователь может взаимодействовать с ним с помощью мыши. Значение по умолчанию — true.

Это свойство удобно использовать, когда кнопка создается с помощью экземпляра класса Sprite (а не класса SimpleButton). Когда для создания кнопки используется экземпляр Sprite, при желании можно украсить кнопку с помощью метода addChild(), добавив дополнительные экземпляры Sprite. Этот процесс может вызывать непредвиденное поведение событий мыши, так как целевым объектом события мыши вместо родительского экземпляра могут стать экземпляры Sprite, добавленные в качестве потомков. Чтобы родительский экземпляр гарантированно быть целевым объектом событий мыши, можно задать его свойству mouseChildren значение false.

При настройке данного свойства события не отправляются. Чтобы создать интерактивные функции, необходимо использовать метод addEventListener().

Ссылка на объект NativeWindow, содержащий данную рабочую область.

Данное окно представляет собственное окно ОС, а рабочая область — его содержимое. Данное свойство может быть использовано только при работе в среде AIR. В проигрывателе Flash Player (при просмотре содержимого в обозревателе) значением данного свойства является null.

Возвращает число потомков данного объекта.

Значение класса StageQuality, определяющее, какое качество визуализации следует применять. Ниже приводятся допустимые значения.

• StageQuality.LOW — низкое качество визуализации. Графика не сглаживается, растровые изображения также не смягчаются. Этот параметр не поддерживается в Adobe AIR.
• StageQuality.MEDIUM — среднее качество визуализации. Графика сглаживается по сетке 2 x 2 пиксела, растровые изображения не смягчаются. Этот параметр подходит для роликов, не содержащих текста. Этот параметр не поддерживается в Adobe AIR.
• StageQuality.HIGH — высокое качество визуализации. Графика сглаживается по сетке 4 x 4 пиксела, растровые изображения смягчаются, если ролик статичен. Этот параметр качества визуализации используется проигрывателем Flash Player по умолчанию.
• StageQuality.BEST — Очень высокое качество визуализации. Графика сглаживается по сетке 4 x 4 пиксела, растровые изображения всегда смягчаются.

Более высокие параметры качества обеспечивают более качественную визуализацию масштабированных растровых изображений. Однако, это происходит за счет увеличения нагрузки на ресурсы системы. В частности, параметр высокого качества при визуализации масштабированного видео может привести к падению частоты кадров.

При воспроизведении содержимого в Adobe AIR можно установить параметр quality в значение StageQuality.BEST или StageQuality.HIGH (значением по умолчанию является StageQuality.HIGH). Изменение значения параметра на другое ни к чему не приводит (значение свойства остается неизменным).

При работе с содержимым в Adobe AIR настройка свойства quality одного объекта Stage приводит к изменению качества визуализации всех объектов Stage (используемых разными объектами NativeWindow).

См. также

Значение класса StageScaleMode, задающее режим масштабирования. Ниже приводятся допустимые значения.

• StageScaleMode.EXACT_FIT — Задает видимость всего приложения в указанной области. При этом исходное соотношение сторон не поддерживается. Может возникнуть искажение изображения, в результате чего приложение может выглядеть растянутым или сжатым.
• StageScaleMode.SHOW_ALL — Задает видимость всего приложения в указанной области без искажений при поддержании исходного соотношения сторон приложения. С двух сторон от приложения могут появиться поля.
• StageScaleMode.NO_BORDER — Задает заполнение указанной области приложением без искажений, но с возможным усечением. При этом поддерживается исходное соотношение сторон приложения.
• StageScaleMode.NO_SCALE — Фиксируется размер всего приложения, так что он сохраняется даже при изменении размеров окна проигрывателя. Если окно проигрывателя меньше размеров содержимого, может возникнуть усечение.

См. также

Задает отображение или скрытие элементов по умолчанию в контекстном меню Flash Player.

Если свойство showDefaultContextMenu имеет значение true (по умолчанию), то появляются все элементы контекстного меню. Если свойство showDefaultContextMenu имеет значение false, отображаются только элементы меню "Параметры" и "О проигрывателе Adobe Flash Player".

Определяет, должна ли отображаться светящаяся рамка вокруг объектов в фокусе.

Текущая высота объекта Stage в пикселах.

Если задать для свойства Stage.scaleMode значение StageScaleMode.NO_SCALE, когда пользователь изменяет размеры окна, содержимое рабочей области сохраняет заданный размер, а свойство stageHeight изменяется, отражая новую высоту области экрана, занимаемой SWF-файлом. (В остальных режимах масштабирования свойство stageHeight всегда отражает исходную высоту SWF-файла.) Можно добавить прослушиватель для события resize, а затем использовать свойство stageHeight класса Stage, чтобы определять фактические размеры в пикселах измененного окна проигрывателя Flash Player. Прослушиватель событий позволяет контролировать, как содержимое экрана корректируется, когда пользователь изменяет размер окна.

Примечание. На HTML-странице, содержащей SWF-файл атрибуты height тегов object и embed должны быть выражены в процентах (например, 100%), а не в пикселах. Если параметры определяются кодом JavaScript, то параметр height метода AC_FL_RunContent() также необходимо настроить на представление в процентах. Эти проценты применяются к значению stageHeight.

См. также

Задает текущую ширину объекта Stage в пикселах.

Если задать для свойства Stage.scaleMode значение StageScaleMode.NO_SCALE, когда пользователь изменяет размеры окна, содержимое рабочей области сохраняет заданный размер, а свойство stageWidth изменяется, отражая новую ширину области экрана, занимаемой SWF-файлом. (В остальных режимах масштабирования свойство stageWidth всегда отражает исходную ширину SWF-файла.) Можно добавить прослушиватель для события resize, а затем использовать свойство stageWidth класса Stage, чтобы определять фактические размеры в пикселах измененного окна проигрывателя Flash Player. Прослушиватель событий позволяет контролировать, как содержимое экрана корректируется, когда пользователь изменяет размер окна.

Примечание. На HTML-странице, содержащей SWF-файл атрибуты width тегов object и embed должны быть выражены в процентах (например, 100%), а не в пикселах. Если параметры определяются кодом JavaScript, то параметр width метода AC_FL_RunContent() также необходимо настроить на представление в процентах. Эти проценты применяются к значению stageWidth.

См. также

Определяет, включен ли переход между потомками объекта с помощью клавиши Tab. Включает или отключает переход между потомками объекта с помощью клавиши Tab. Значение по умолчанию — true.

Возвращает объект TextSnapshot для данного экземпляра DisplayObjectContainer.

Указывает ширину экранного объекта в пикселах. Ширина вычисляется на основе границ содержимого экранного объекта. Когда задается свойство width, соответствующим образом изменяется и свойство scaleX, как показано в следующем коде.

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleX) // 1;
    rect.width = 200;
    trace(rect.scaleX) // 2;

За исключением объектов TextField и Video, экранные объекты без содержимого (например, пустой спрайт), имеют ширину 0, даже если задать свойству width другое значение.

Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer. Потомок добавляется перед (сверху) всех остальных потомков в данном экземпляре DisplayObjectContainer. (Чтобы добавить потомка в конкретную позицию в индексе, используйте метод addChildAt().)

Если добавляется объект, предком которого уже является другой контейнер экранных объектов, то он удаляется из списка потомков старого контейнера.

Параметры

Добавляет дочерний экземпляр DisplayObject к данному экземпляру DisplayObjectContainer. Потомок добавляется в указанной позиции индекса. Индекс 0 обозначает конец списка отображения для данного объекта DisplayObjectContainer.

Так, в следующем примере показано три разных объекта с именами a, b и c в позициях индекса 0, 2 и 1 соответственно.

Если добавляется объект, предком которого уже является другой контейнер экранных объектов, то он удаляется из списка потомков старого контейнера.

Параметры

Регистрирует объект прослушивателя события в объекте EventDispatcher, в результате чего прослушиватель будет получать уведомления о событиях. Регистрировать прослушиватели событий можно во всех узлах списка отображения для определенного типа события, фазы и приоритета.

После успешной регистрации прослушивателя событий нельзя изменить его приоритет путем дополнительных вызовов метода addEventListener(). Чтобы изменить приоритет прослушивателя, необходимо сначала вызвать метод removeListener(). Затем можно зарегистрировать прослушиватель еще раз с новым уровнем приоритета.

Следует учесть, что после регистрации прослушивателя последующие вызовы метода addEventListener() с другим значением свойства type или useCapture приводят к регистрации другого прослушивателя. Например, если сначала был зарегистрирован прослушиватель со свойством useCapture в значении true, он прослушивает события только в фазе захвата. Если вызвать метод addEventListener() еще раз с тем же объектом прослушивателя, но со свойством useCapture в значении false, то будет два прослушивателя: один — прослушивающий в фазе захвата, а другой — в фазах назначения и восходящей цепочки.

Нельзя зарегистрировать прослушиватель событий только для фазы цели или только для фазы пузырей. Эти фазы объединяются при регистрации, так как фаза пузырей применяется только к предкам целевого узла.

Если прослушиватель событий больше не нужен, его можно удалить, вызвав метод removeEventListener(); иначе могут возникнуть проблемы с памятью. Объекты с зарегистрированным прослушивателями событий не очищаются из памяти автоматически, так как сборщик мусора не удаляет объекты, на которые есть ссылки.

Копирование экземпляра EventDispatcher не приведет к копированию всех присоединенных к нему прослушивателей событий. (Если для вновь созданного узла требуется прослушиватель событий, его необходимо добавить после создания узла.) Однако если экземпляр EventDispatcher перемещается, все зарегистрированные для него прослушиватели событий перемещаются вместе с ним.

Если прослушиватель регистрируется для узла в тот момент, когда на нем обрабатывается событие, то в текущей фазе он не запускается, однако может запуститься в следующей фазе потока события, например в фазе пузырей.

Если прослушиватель событий удаляется из узла в момент обработки события, он все равно запускается текущими действиями. После удаления прослушиватель событий больше не вызывается (если не будет снова зарегистрирован для дальнейшей обработки).

Параметры

Задает фокус клавиатуры на интерактивном объекте, указанном в objectToFocus. Направление фокуса устанавливается параметром direction.

Направление фокуса должно задаваться приложением (или средой приложения). Как такового встроенного принципа расположения интерактивных объектов не существует, однако, для их упорядочения можно использовать ряд доступных свойств. Например, можно сортировать интерактивные объекты в рабочей области по их положению в списке отображения. Вызов метода assignFocus() идентичен параметру свойства Stage.focus с дополнительной возможностью указывать направление, откуда этот фокус поступает.

После получения фокуса objectToFocus отправляет событие focusIn. Свойство direction объекта FocusEvent сообщает о настройке параметра direction.

При назначении объекта HTMLLoader параметру objectToFocus объект HTMLLoader выбирает подходящий объект для передачи фокуса в HTML DOM, принимая во внимание значение параметра direction. При использовании FocusDirection.BOTTOM фокус передается объекту в HTML DOM, который находится в конце списка отображения. При использовании FocusDirection.TOP фокус передается объекту в HTML DOM, который находится в начале списка отображения. При использовании NONE объект HTMLLoader получает фокус, а его текущий элемент с фокусом не меняется.

Параметры

См. также

Передает событие в поток событий. Целью события является объект EventDispatcher, для которого вызывается метод dispatchEvent().

Параметры

Проверяет наличие у объекта EventDispatcher прослушивателей событий, которые зарегистрированы для получения уведомлений о событиях определенного типа. Это позволяет определить, где объект EventDispatcher изменил обработку типа события в иерархии потока событий. Чтобы определить, запускает ли на самом деле определенный тип событий прослушиватель, используйте метод willTrigger().

Разница между hasEventListener() и willTrigger() заключается в том, что hasEventListener() просматривает только тот объект, которому принадлежит, а willTrigger() просматривает весь поток событий для события, указанного в параметре type.

Когда метод hasEventListener() вызывается из объекта LoaderInfo, учитываются только те прослушиватели, к которым есть доступ у вызывающего объекта.

Параметры

Вызов метода invalidate() предписывает проигрывателю Flash Player оповестить экранные объекты о следующей возможности визуализации списка отображения (например, когда точка воспроизведения приближается к новому кадру). После вызова методаinvalidate() при дальнейшей визуализации списка отображения проигрыватель Flash Player отправляет событие render каждому экранному объекту, зарегистрированному для прослушивания события render. Метод invalidate() необходимо вызвать каждый раз, когда нужно, чтобы проигрыватель Flash Player отправлял события render.

Событие render дает возможность вносить изменения в список отображения непосредственно перед его визуализацией. Это позволяет откладывать обновления списка отображения до самой последней возможности. Это может увеличить производительность путем предотвращения ненужных обновлений экрана.

Событие render отправляется только тем экранным объектам, которые находятся в том же защищенном домене, что и код, вызывающий метод stage.invalidate(), или экранным объектам из защищенного домена, которому предоставлено разрешение через метод Security.allowDomain().

См. также

Определяет, должно ли свойство Stage.focus возвращать значение null по соображениям безопасности. Другими словами, isFocusInaccessible имеет значение true, если объект в фокусе принадлежит к изолированной программной среде безопасности, к которой у SWF-файла нет доступа.

Удаляет дочерний DisplayObject из заданной позиции индекса в списке потомков DisplayObjectContainer. Свойство parent удаленного потомка получает значение null, а сам объект очищается, если нет других ссылок на потомка. Позиции индекса экранных объектов, расположенных над потомком в DisplayObjectContainer уменьшаются на 1.

Сборка мусора — это процесс, с помощью которого проигрыватель Flash Player перераспределяет неиспользуемую память. Когда на переменную или объект больше нет ссылок или он хранится в другом месте, сборщик мусора очищает и утилизирует память, которую он занимал, при условии отсутствия ссылок

Параметры

Изменяет положение существующего потомка в DisplayObjectContainer. Это отражается на иерархическом представлении дочерних объектов. Так, в следующем примере показано три разных объекта с именами a, b и c в позициях индекса 0, 1 и 2 соответственно.

Когда используется метод setChildIndex() и указывается уже занятая позиция индекса, меняются только позиции между прежней и новой позицией экранного объекта. Все остальные остаются без изменения. Если потомок перемещается на более НИЗКУЮ позицию, позиции всех потомков между этими позициями станут на 1 ВЫШЕ. Если потомок перемещается на более ВЫСОКУЮ позицию, позиции всех потомков между этими позициями станут на 1 НИЖЕ. Например, если контейнер экранных объектов из прошлого примера имеет имя container, можно поменять позициями экранные объекты с именами a и b, вызвав следующий код:

container.setChildIndex(container.getChildAt(1), 0);

В результате этого объекты выстраиваются следующим образом:

Параметры

Меняет местами (в порядке "от начала к концу") дочерние объекты, расположенные в двух заданных позициях индекса в списке потомков. Все остальные дочерние объекты в контейнере экранных объектов остаются на прежних позициях.

Параметры

Проверяет, зарегистрирован ли прослушиватель событий в объекте EventDispatcher или в любом из его предков для получения уведомлений о событиях определенного типа. Этот метод возвращает значение true, если прослушиватель событий запускается в любой фазе потока событий, когда событие заданного типа отправляется данному объекту EventDispatcher или его потомкам.

Разница между методами hasEventListener() и willTrigger() заключается в том, что hasEventListener() просматривает только тот объект, которому принадлежит, а willTrigger() просматривает весь поток событий для события, указанного в параметре type.

Когда метод willTrigger() вызывается из объекта LoaderInfo, учитываются только те прослушиватели, к которым есть доступ у вызывающего объекта.

Параметры

Отправляется, когда объект Stage переходит в полноэкранный режим или выходит из этого режима. Изменение в полноэкранном режиме можно инициировать через ActionScript, либо при нажатии комбинации клавиш пользователем, либо если текущий фокус покидает окно, находящееся в полноэкранном режиме.

Данное событие имеет следующие свойства.

Отправляется объектом Stage, когда курсор мыши покидает рабочую область.

Данное событие имеет следующие свойства.

Отправляется, когда свойство scaleMode объекта Stage установлено в значение StageScaleMode.NO_SCALE и изменяется размер SWF-файла.

Данное событие имеет следующие свойства.

1. Сначала конструктор класса настраивает приложение Flash для фиксации, независимо от размера окна проигрывателя Flash Player, а затем добавляет два прослушивателя событий с методами activateHandler() и resizeHandler().
2. Метод activateHandler() запускается при щелчке левой кнопкой мыши.
3. Метод resizeHandler() запускается при изменении размеров рабочего стола.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}