Определяет или задает значение, указывающее, поддерживает ли компонент взаимодействие с пользователем. Значение true указывает, что компонент поддерживает взаимодействие с пользователем; значение false указывает на то, что оно не поддерживает его.

Если присвоить свойству enabled значение false, цвет контейнера становится тусклым, а данные, вводимые пользователем, блокируются (за исключением компонентов Label и ProgressBar).

Значение по умолчанию true

Определяет или задает режим редактора методов ввода (IME). IME дает пользователям возможность воспользоваться клавиатурой QWERTY для ввода символов из наборов для китайского, японского и корейского языков.

Программа Flash переводит IME в указанный режим, когда компонент оказывается в фокусе, и восстанавливает исходное значение после того, как он выходит из фокуса.

Класс flash.system.IMEConversionMode определяет константы для действительных значений этого свойства. Присвойте этому свойству значение null, чтобы предотвратить применение IME по отношению к этому компоненту.

Определяет или задает максимальное значение в последовательности чисел.

Значение по умолчанию 10

Определяет или задает минимальное значение в последовательности чисел.

Значение по умолчанию 0

Определяет следующее значение в последовательности значений.

Определяет предыдущее значение в последовательности значений.

Определяет или задает ненулевое число, указывающее шаг изменения значений. Значение свойства value является кратным этому числу за вычетом минимального значения. Компонент NumericStepper округляет итоговое значение до ближайшего размера шага.

Значение по умолчанию 1

Определяет ссылку на компонент TextInput, который содержится в компоненте NumericStepper. Воспользуйтесь этим свойством для доступа и манипулирования основным компонентом TextInput. Например, это свойство можно использовать для изменения текущей выделенной области в текстовом окне или ограничения набора поддерживаемых этим полем символов.

Определяет или задает текущее значение компонента NumericStepper.

Значение по умолчанию 1

Создает новый экземпляр компонента NumericStepper.

Отображает или скрывает индикатор фокуса этого компонента.

Класс UIComponent реализует этот метод путем создания и размещения экземпляра класса, указанного стилем focusSkin.

Параметры

Возвращает карту стилей по умолчанию для текущего компонента. Карта стилей содержит тип, который подходит для компонента в зависимости от стиля, используемого компонентом. Например, стиль disabledTextFormat содержит значение null или объект TextFormat. Вы можете воспользоваться этими стилями и вызвать метод setStyle() по отношению к текущему компоненту. Следующий код переопределяет стиль disabledTextFormat, выбранный по умолчанию для указанного компонента:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

См. также

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Задает фокус для экземпляра компонента.

Отправляется при изменении пользователем значения в компоненте NumericStepper.

Примечание. Это событие на отправляется, если для изменения этого значения используется ActionScript.

Данное событие имеет следующие свойства.

1. Добавьте компонент NumericStepper в свою библиотеку.
2. Сохраните этот код под именем NumericStepperExample.as в том же каталоге, где и FLA-файл.
3. Присвойте параметру DocumentClass в FLA-файле значение NumericStepperExample.

package 
{
    import flash.display.Sprite
    import flash.text.TextField;
    import flash.events.Event;
    import fl.controls.NumericStepper;
    
    public class NumericStepperExample extends Sprite
    {
        private var ns1:NumericStepper;
        private var ns2:NumericStepper;
        private var tf1:TextField;
        private var tf2:TextField;
        private var rowHeight1:Number = 10;
        private var rowHeight2:Number = 50;
        
        public function NumericStepperExample() {        
            setupSteppers();
            setupTextFields();
        }
        private function setupTextFields():void {
            tf1 = new TextField();
            tf1.text = "This stepper increments by 1 between 0 and 5. Disables if it reaches 0.";
            tf1.autoSize = "left";
            tf1.x = 100;
            tf1.y = rowHeight1;
            addChild(tf1);
            
            tf2 = new TextField();
            tf2.text = "This stepper increments by 0.01 between 0 and 20. Disables if it reaches 0.";
            tf2.autoSize = "left";
            tf2.x = 100;
            tf2.y = rowHeight2;
            addChild(tf2);
        }
        private function setupSteppers():void {    
            ns1 = new NumericStepper();
            ns1.stepSize = 1;
            ns1.maximum = 5;
            ns1.minimum = 0;
            ns1.addEventListener(Event.CHANGE,changeOccurred);
            ns1.move(10,rowHeight1);
            addChild(ns1);

            ns2 = new NumericStepper();
            ns2.stepSize = 0.01;
            ns2.maximum = 20;
            ns2.minimum = 0;
            ns2.value = 10;
            ns2.addEventListener(Event.CHANGE,changeOccurred);
            ns2.move(10,rowHeight2);
            addChild(ns2);
        }
        private function changeOccurred(e:Event):void {
            var nsTarget:NumericStepper = e.target as NumericStepper;
            if(nsTarget.value == 0) nsTarget.enabled = false;
        }
    }
}