Определяет или задает строку, в которой указано, каким образом размер и выравнивание метки подгоняются под значение ее свойства text. Ниже приводятся допустимые значения.

• TextFieldAutoSize.NONE: размер и выравнивание метки не подгоняются под текст.
• TextFieldAutoSize.LEFT: правая и нижняя стороны метки смещаются, исходя из размера текста. Левая и верхняя стороны метки не смещаются.
• TextFieldAutoSize.CENTER: левая и правая стороны метки смещаются, исходя из размеров текста. Центр метки по горизонтали сохраняет привязку к исходному положению.
• TextFieldAutoSize.RIGHT: левая и нижняя стороны метки смещаются, исходя из размера текста. Верхняя и правая стороны метки не смещаются.

Значение по умолчанию TextFieldAutoSize.NONE

См. также

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Определяет или задает значение, управляющее удалением лишних разделителей (например, пробелов и разрывов строк) из компонента Label, в котором есть текст HTML. Значение true указывает на то, что свободное место необходимо удалить; значение false указывает на то, что оно остается.

Свойство condenseWhite влияет на текст, заданный только с помощью свойства htmlText, а не с помощью свойства text. Если текст задается с помощью свойства text, свойство condenseWhite игнорируется.

Если свойству condenseWhite присваивается значение true, необходимо использовать стандартные команды HTML (например, <br> и <p>), чтобы обозначить разрыв строк в тексте из текстового поля.

Значение по умолчанию false

См. также

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Определяет или задает высоту компонента (в пикселах).

Настройка этого свойства приводит к отправке события resize. Чтобы получить подробную информацию о времени отправки события resize, перейдите по одноименной ссылке.

Если свойству scaleY компонента присвоено значение, отличное от 1,0, высота компонента, определяемая по его внутренним координатам, не будет совпадать со значением высоты для координат родительского объекта. Например, компонент высотой 100 пикселов, свойство scaleY которого равно 2, имеет значение, равное 100 пикселам в родительском объекте. При этом сохраняется внутреннее значение, указывающее, что его высота равна 50 пикселам.

См. также

Определяет или задает текст, отображаемый компонентом Label, включая разметку HTML, отражающую стили данного текста. В этом свойстве можно указать текст в формате HTML, воспользовавшись подмножеством тегов HTML, которые поддерживаются объектом TextField.

Если значение по умолчанию свойства text изменено в инспекторе свойств, то измененное значение имеет преимущество перед любым значением, указанным в поле htmlText инспектора свойств. Чтобы воспользоваться свойством htmlText в инспекторе свойств, поле свойства text должно содержать значение Label в точности так, как это показано. При кодировании с помощью ActionScript не требуется устанавливать значение свойства text; значением по умолчанию является Label.

Значение по умолчанию ""

См. также

Определяет или задает значение, указывающее, можно ли выбрать текст. Значение true указывает, что его можно выбрать; значение false говорит о том, что выделение невозможно.

Пользователь может скопировать текст с возможностью выделения из компонента Label.

Значение по умолчанию false

Определяет или задает обычный текст, отображаемый компонентом Label.

Учтите, что символы, которые представляют разметку HTML, не имеют особого смысла в контексте строки и будут появляться на экране по мере ввода.

Чтобы показать текст, который содержит теги HTML, воспользуйтесь свойством htmlText. HTML заменяет любой пользовательский текст при помощи свойства htmlText, а свойство text возвращает версию текста HTML в виде обычного текста без тегов HTML.

Если значение по умолчанию свойства text изменено в инспекторе свойств, оно имеет преимущество перед свойством htmlText в инспекторе свойств.

Значение по умолчанию "Label"

См. также

Ссылка на внутреннее текстовое поле компонента Label.

Определяет или задает ширину компонента (в пикселах).

Настройка этого свойства приводит к отправке события resize. Чтобы получить подробную информацию о времени отправки события resize, перейдите по одноименной ссылке.

Если свойству scaleX компонента присвоено значение, отличное от 1,0, ширина компонента, определяемая по его внутренним координатам, не будет совпадать со значением ширины для координат родительского объекта. Например, компонент шириной 100 пикселов, свойство scaleX которого равно 2, имеет значение, равное 100 пикселам в родительском объекте. При этом сохраняется внутреннее значение, указывающее, что его ширина равна 50 пикселам.

См. также

Определяет или задает значение, указывающее, поддерживает ли текстовое поле перенос по словам. Значение true указывает на наличие переноса; значение false говорит о его отсутствии.

Значение по умолчанию false

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Создает новый экземпляр компонента Label.

Возвращает карту стилей по умолчанию для текущего компонента. Карта стилей содержит тип, который подходит для компонента в зависимости от стиля, используемого компонентом. Например, стиль disabledTextFormat содержит значение null или объект TextFormat. Вы можете воспользоваться этими стилями и вызвать метод setStyle() по отношению к текущему компоненту. Следующий код переопределяет стиль disabledTextFormat, выбранный по умолчанию для указанного компонента:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

См. также

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Отправляется, когда изменяется ширина или высота компонента.

Примечание. Это событие не происходит, если для изменения текста метки используется код ActionScript.

Данное событие имеет следующие свойства.

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Добавьте компоненты Label и Button в свою библиотеку.
2. Сохраните этот код под именем LabelExample.as в том же каталоге, где и FLA-файл.
3. Присвойте параметру DocumentClass в FLA-файле значение LabelExample.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}