Показывает активность клавиши Alt: true — активна, false — неактивна. Поддерживается только для операционных систем Windows.

Показывает, нажата ли основная кнопка мыши: true — да, false — нет.

Показывает активность клавиши Control: true — активна, false — неактивна. В компьютерах Macintosh это свойство необходимо использовать для представления клавиши Command.

Показывает расстояние прокрутки в строках на единицу вращения колесика мыши. Положительное значение delta показывает прокручивание вверх, отрицательное значение показывает прокрутку вниз. Как правило, используются значения в пределах 1-3, но более быстром прокручивании это число увеличивается. Этот параметр от устройства и операционной системы, как правило оно может настраиваться пользователем. Это свойство применяется только к событию MouseEvent.mouseWheel.

Горизонтальная координата события относительно спрайта-контейнера.

Вертикальная координата события относительно спрайта-контейнера.

Ссылка на объект списка отображения, связанный с событием. Например, когда происходит событие mouseOut, relatedObject представляет объект списка отображения, на который теперь показывает указатель. Это свойство применяется только к событиям mouseOut и mouseOver.

Показывает активность клавиши Shift: true — активна, false — неактивна.

Горизонтальная координата события в глобальных координатах рабочей области. Это свойство вычисляется, когда задано свойство localX.

Вертикальная координата события в глобальных координатах рабочей области. Это свойство вычисляется, когда задано свойство localY.

Создает объект Event, содержащий данные о событиях mouse. Объекты Event передаются прослушивателям событий в качестве параметров.

Создает копию объекта MouseEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает строку, содержащую все свойства объекта MouseEvent. Строка имеет следующий формат:

[MouseEvent type=значение bubbles=значение cancelable=значение ... delta=значение]

Предписывает проигрывателю Flash Player выполнить визуализацию после обработки данного события, если список отображения был изменен.

Задает значение свойства type для объекта события click.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события doubleClick. Свойство doubleClickEnabled должно иметь значение true, чтобы объект мог генерировать событие doubleClick.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события mouseDown.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события mouseMove.

Данное событие имеет следующие свойства.

См. также

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Задает значение свойства type для объекта события mouseOut.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события mouseOver.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type объекта события mouseUp.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события mouseWheel.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события rollOut.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события rollOver.

Данное событие имеет следующие свойства.

См. также

1. Заявляются свойства для размера (100 x 100 пикселов) и фонового цвета (оранжевый) для последующего использования при рисовании квадрата.
2. Конструктор создает новый объект ChildSprite с именем child. Его конструктор сначала рисует квадрат 100 x 100 пикселов в точке с координатами (0,0) путем вызова метода draw(), а затем добавляет семь прослушивателей событий с подписчиками.
   • click/clickHandler(): отправляется, когда пользователь один раз щелкает квадрат левой кнопкой мыши.
   • doubleClick/doubleClickHandler(): отправляется, когда пользователь дважды щелкает квадрат левой кнопкой мыши.
   • mouseDown/mouseDownHandler(): когда объект ChildSprite (оранжевый квадрат) получает щелчок, на экране печатается сообщение trace(), а затем вызывается метод ChildSprite.draw(), рисующий темно-желтый квадрат вместо голубого, нарисованного методом mouseOverHandler(). Метод mouseDownHandler() также добавляет прослушиватель событий mouseMove и подписчик mouseMoveHandler() (как описано ниже, обрабатывающий перемещение мыши. Затем вызывается метод startDrag(), позволяющий перетаскивать объект Sprite.
   • mouseOut/mouseOutHandler(): отправляется, когда указатель покидает область квадрата. Вызывается метод draw(), чтобы вернуть квадрату обычный размер и цвет.
   • mouseOver/mouseOverHandler(): отправляется, когда указатель мыши находится над квадратом. Этот метод перерисовывает квадрат так, что он становится больше, а фон становится темно-желтым.
   • mouseUp/mouseUpHandler(): когда пользователь отпускает кнопку мыши, прослушиватель события mouseMove удаляется и вызывается метод stopDrag фиксирующий местоположение квадрата.
   • mouseMove/mouseMoveHandler(): вызывается в рамках функции mouseDownHandler() и отправляется, когда пользователь удерживает левую кнопку мыши и перетаскивает квадрат.
   • mouseWheel/mouseWheelHandler(): отправляется, когда пользователь прокручивает колесо мыши над квадратом.
3. Затем экземпляр ChildSprite с именем child добавляется в список отображения с помощью метода addChild(), который быстро рисует оранжевый квадрат.

Примечания.

• Класс MouseEventExample должен быть в корне документа.
• Некоторые из перечисленных выше методов событий объявляют локальную переменную sprite, которой присваивается значение event.target типа Sprite.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}