Показывает активность клавиши Alt: true — активна, false — неактивна. Поддерживается только для операционных систем Windows.

Содержит значение кода символа для нажатой или отпущенной клавиши. Значения кодов символов являются значениями английской раскладки клавиатуры. Например, если нажать "Shift+3", charCode — это символ "#" японской раскладке клавиатуры так же, как на английской.

Примечание. Если работает редактор метода ввода (IME), charCode не сообщает точные коды символов.

См. также

Показывает активность клавиши Control: true — активна, false — неактивна.

Примечание. Клавиша Command в системах Macintosh должна представляться с использованием этого модификатора клавиши.

Значение кода клавиши для нажатой или отпущенной клавиши.

Примечание. Если работает редактор метода ввода (IME), charCode не сообщает точные коды клавиш.

См. также

Указывает расположение клавиши на клавиатуре. Это полезно для дифференциации клавиш, встречающихся на клавиатуре несколько раз. Например, можно дифференцировать левую и правую клавиши Shift по значению этого свойства: KeyLocation.LEFT — левая, а KeyLocation.RIGHT — правая. Другой пример — дифференциация клавиш с цифрами, нажатых на стандартной клавиатуре (KeyLocation.STANDARD) и на числовой панели (KeyLocation.NUM_PAD).

Показывает, активирован ли модификатор клавиши Shift: true — активирован, false — не активирован.

Создает объект Event, содержащий данные о событиях клавиатуры. Объекты Event передаются прослушивателям событий в качестве параметров.

См. также

Создает копию объекта KeyboardEvent и задает значение каждого свойства, совпадающее с оригиналом.

Возвращает строку, содержащую все свойства объекта KeyboardEvent. Строка имеет следующий формат:

[KeyboardEvent type=значение bubbles=значение cancelable=значение ... shiftKey=значение]

Предписывает проигрывателю Flash Player выполнить визуализацию после обработки данного события, если список отображения был изменен

Задает значение свойства type для объекта события keyDown.

Данное событие имеет следующие свойства.

См. также

Задает значение свойства type для объекта события keyUp.

Данное событие имеет следующие свойства.

См. также

1. Создается новый экземпляр Sprite с именем child.
2. Объявляются свойства для последующего использования при задании фонового цвета и размера квадрата.
3. С помощью методов объекта Sprite рисуется голубой квадрат, отображаемый в рабочей области в точке по умолчанию с координатами (0,0) путем вызова метода addChild().
4. Добавляется один прослушиватель событий мыши и два прослушивателя событий клавиатуры:
   • click/clickHandler отправляется при щелчке по квадрату с целью перевода фокуса на спрайт child, чтобы он мог прослушивать события клавиатуры;
   • keyDown/keyDownHandler отправляется при нажатии любой клавиши; Метод подписчика печатает сведения о событии с помощью инструкции trace();
   • keyUp/keyUpHandler отправляется, когда клавиша отпускается.

При тестировании этого примера сначала необходимо щелкнуть по квадрату, чтобы заработали события клавиатуры.

Также, если используется команда "Тестировать ролик" в программе разработки Flash, на некоторые клавиши может реагировать интерфейс программы, а не прослушиватели событий, добавленный для дочернего спрайта.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.*;

    public class KeyboardEventExample extends Sprite {
        private var child:Sprite = new Sprite();
        private var bgColor:uint = 0x00CCFF;
        private var size:uint = 80;

        public function KeyboardEventExample() {
            child.graphics.beginFill(bgColor);
            child.graphics.drawRect(0, 0, size, size);
            child.graphics.endFill();
            addChild(child);
            child.addEventListener(MouseEvent.CLICK, clickHandler);
            child.addEventListener(KeyboardEvent.KEY_DOWN, keyDownHandler);
            child.addEventListener(KeyboardEvent.KEY_UP, keyUpHandler);
            
        }

        private function clickHandler(event:MouseEvent):void {
            stage.focus = child;
        }

        private function keyDownHandler(event:KeyboardEvent):void {
            trace("keyDownHandler: " + event.keyCode);
            trace("ctrlKey: " + event.ctrlKey);
            trace("keyLocation: " + event.keyLocation);
            trace("shiftKey: " + event.shiftKey);
            trace("altKey: " + event.altKey);

        }

        private function keyUpHandler(event:KeyboardEvent):void {
            trace("keyUpHandler: " + event.keyCode);
        }
        
        
    }
}