В этом объекте Clipboard находится массив строк, в котором содержатся имена поддерживаемых форматов данных.

Константы имен стандартных форматов содержатся в классе ClipboardFormats. Задаваемые приложением строки могут также использоваться в качестве имен форматов для передачи данных в виде объектов.

См. также

 var availableFormats:Array = Clipboard.generalClipboard.formats;

Буфер обмена ОС.

Любые данные, передаваемые в буфер обмена, доступны другим приложениям. По этой причине возможно удаленное выполнение вредоносного кода в веб-обозревателе.

Примечание к Flash Player 10. В целях безопасности в приложениях Flash Player 10 операция вставки может быть инициирована только пользователем, а не Actionscript. Метод Clipboard.getData() возвратит содержимое буфера обмена только в том случае, если InteractiveObject получил и обрабатывает событие paste. При любых обстоятельствах вызов метода Clipboard.getData() ни к чему не приведет.

Объект generalClipboard создается автоматически. Присвоить данному свойству другой экземпляр объекта Clipboard невозможно. Вместо этого для чтения и записи данных в уже существующий объект используйте методы getData() и setData().

Перед тем как записывать в буфер обмена новые данные, следует удалить из него предыдущие данные всех форматов.

Создает пустой объект Clipboard.

См. также

Удаляет все представления данных из этого объекта Clipboard.

 Clipboard.generalClipboard.clear();

Удаляет представления данных заданного формата.

Параметры

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Определяет данные из буфера обмена, если они существуют в указанном формате.

При доступе к данным стандартного формата, данные возвращаются в качестве нового объекта соответствующего типа Flash Player или AIR.

При доступе к данным в формате, указанном приложением, значение параметра transferMode определяет, возвращать ли ссылку на исходный объект или анонимный объект, содержащий сериализованную копию исходного объекта. Если при использовании режима originalPreferred или clonePreferred предпочтительная версия недоступна, Flash Player или AIR возвращает альтернативную версию. Если при использовании режиме originalOnly или cloneOnly запрашиваемая версия недоступна, Flash Player или AIR возвращает undefined.

Параметры

См. также

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Проверяет наличие данных указанного формата в данном объекте Clipboard.

Для проверки наличия данных стандартных форматов используйте константы класса ClipboardFormats.

Параметры

См. также

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Добавляет представление информации для передачи данных в указанном формате данных.

Различные представления одной и той же информации может храниться в буфере обмена в нескольких форматах. Это сделано для того, чтобы различные приложения или компоненты смогли воспользоваться доступными данными. Например, в приложении AIR изображение может быть добавлено: в растровом формате для использования в редакторах изображений, в качестве объекта Bitmap для использования в любом другом приложении AIR, в качестве закодированного PNG-файла для передачи в собственную файловую систему.

Параметр data должен относиться к типу данных, соответствующему указанному формату.

Имя пользовательского формата не может начинаться со слов "air:" или "flash:". В приложении AIR, во избежание совпадения имен при использовании пользовательских форматов, в качестве префикса к формату можно добавить идентификатор вашего приложения или имя пакета, например com.example.applicationName.dataPacket.

При передаче данных внутри или между приложениями Flash Player или AIR параметр serializable определяет, являются ли доступными и ссылка, и копия или только ссылка на объект. Задайте для параметра serializable значение true, чтобы сделать доступными и ссылку и копию объекта данных. Задайте для параметра serializable значение false, чтобы сделать доступной только ссылку на объект. Ссылки на объекты действуют только в текущем приложении, поэтому установка параметра serializable на значение false, также означает, что данные такого формата недоступны для других приложений Flash Player или AIR. Компонент может выбрать между получением ссылки на объект или копии объекта, установив соответствующий режим передачи данных для буфера обмена при доступе к данным формата.

Примечание. Стандартные форматы всегда преобразуются в собственные форматы системы при вставке или перетаскивании (только для AIR) данных вне поддерживаемого приложения, поэтому значение параметра serializable не влияет на доступность данных стандартного формата для приложений, отличных от приложений Flash Player или AIR.

Для отложенной визуализации данных формата используйте метод setDataHandler(). Если оба метода — setData() и setDataHandler() — используются для добавления представления данных с одинаковым именем формата, то функция обработчика не будет вызвана.

Параметры

См. также

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

Добавляет ссылку на функцию обработчика, который по требованию создает данные в указанном формате. Используйте данный метод для того, чтобы отложить создание или визуализация данных до момента доступа к ним.

Функция обработчика должна возвращать соответствующий заданному формату тип данных.

Функция обработчика вызывается только в том случае, если данные заданного формата распознаются. Обратите внимание на то, что данные могут измениться с момента добавления обработчика до момента их считывания, если только ваше приложение не обеспечивает защиту данных. Поведение при многократном считывании данных буфера обмена, представленных функцией обработчика, не гарантировано. Flash Player ли AIR может возвратить данные, созданные при первом вызове функции, или выполнить повторный вызов функции. Не следует полагаться ни на одно из этих поведений.

Для добавления данных непосредственно в этот объект Clipboard используйте метод setData(). Если вызываются оба метода — setData() и setDataHandler() — с одинаковым именем формата, то функция обработчика не будет вызвана.

Параметры

См. также

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Произведите запись данных (в данном случае строковых данных) в Clipboard.generalClipboard.
2. Произведите считывание содержимого буфера обмена из Clipboard.generalClipboard.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void{
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String{
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } else {return null;}
        }
        
    }
}