Значение ascent соответствует расстоянию в пикселах от базовой линии до верхнего края строки. См. "Подъем" в обзорном рисунке для данного класса.

См. также

Значение descent соответствует расстоянию в пикселах от базовой линии до нижнего края строки. См. "Спуск" в обзорном рисунке для данного класса.

См. также

Значение height соответствует высоте в пикселах для текста выбранных строк (необязательно всего текста). Высота строки текста не включает высоту промежуточного поля. См. "Высота строки" в обзорном рисунке для данного класса.

См. также

Значение leading соответствует расстоянию между строками текста. См. "Интервал" в обзорном рисунке для данного класса.

См. также

Значение width соответствует ширине в пикселах для текста выбранных строк (необязательно всего текста). Ширина строки текста не равна ширине текстового поля. Ширина строки текста определяется относительно ширины текстового поля минус ширина промежуточного поля, равного 4 пикселам (по 2 пиксела с каждой стороны). См. "Ширина строки текста" в обзорном рисунке для данного класса.

См. также

Значение x соответствует положению первого символа слева (в пикселах). Это значение включает значения ширины полей, отступов (если они есть) и промежуточного поля. См. "Положение строки текста по оси х" в обзорном рисунке для данного класса.

См. также

Создает объект TextLineMetrics. Объект TextLineMetrics содержит данные о размерах строки текста в пределах текстового поля. Объекты этого класса возвращаются методом flash.text.TextField.getLineMetrics().

См. рисунок в описании этого класса, где данные свойства представлены в контексте.

См. также

1. Создайте свойство типа TextField с именем label.
2. Конструктор вызывает метод configureAssets(), который выполняет следующие задачи:
   • Задает выравнивание рабочей области по верхнему и левому краям и запрещает масштабирование;
   • создает новый объект TextField с именем label;
   • включает фон для label и задает ему белый цвет;
   • разрешает тексту объекта label занимать несколько линий с автоматическим переносом слов;
   • назначает результат вызова метода getLabelText() свойству text объекта label; метод getLabelText() создает переменную типа XML и назначает ее узлу XML с именемbody, который заполняется длинными предложением;
   • добавляет объект label в список отображения с помощью метода addChild().
3. Затем добавляется метод, который прослушивает события resize, происходящие в рабочей области, и называется resizeHandler(). Каждый раз, когда изменяется размер окна проигрывателя Flash Player, отправляется событие RESIZE, затем происходит следующее.
   • Вызывается метод draw(), чтобы объект label находился в центре рабочей области и был окружен буфером шириной десять пикселов.
   • Затем метод setTimeout() вызывает showMetrics() после короткой задержки. Задержка добавляется, так как показатели линии обновляются только после завершения события RESIZE и повторной отрисовки рабочей области.
   • Метод showMetrics() назначает переменную TextLineMetrics с именем metrics результату вызова getLineMetrics(), после чего эта переменная передается новому экземпляру LineMetricsReader с именем reader. Затем эти две переменные используются в вызовах метода trace() для вывода первой (и единственной) строки объекта label и сведений, переданных экземпляром LineMetricsReader с помощью метода toString().
4. Конструктор инициирует одну отправку события resize чтобы обеспечить правильную отрисовку объекта label при первой загрузке SWF-файла.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.*;
    import flash.text.TextField;
    import flash.text.TextLineMetrics;
    import flash.utils.setTimeout;

    public class TextLineMetricsExample extends Sprite {
        private var gutter:int = 10;
        private var label:TextField;

        public function TextLineMetricsExample() {
            configureAssets();
            configureListeners();
            resizeHandler(new Event(Event.RESIZE));
        }

        private function showMetrics():void {
            var metrics:TextLineMetrics = label.getLineMetrics(0);
            var reader:LineMetricsReader = new LineMetricsReader(metrics);
            trace("lineText: " + label.getLineText(0));
            trace("metrics: " + reader);
        }

        private function configureAssets():void {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            label = new TextField();
            label.background = true;
            label.backgroundColor = 0xFFFFFF;
            label.multiline = true;
            label.wordWrap = true;
            label.text = getLabelText();
            addChild(label);
        }

        private function configureListeners():void {
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function resizeHandler(event:Event):void {
            draw();
            setTimeout(showMetrics, 100);
        }

        private function draw():void {
            label.x = gutter;
            label.y = gutter;
            label.width = stage.stageWidth - (gutter * 2);
            label.height = stage.stageHeight - (gutter * 2);
        }

        private function getLabelText():String {
            var text:XML = <body>The Flex product line enables developers to build rich Internet applications that blend the responsiveness of desktop software, the cross-platform reach of the web, and the expressiveness of the Flash Platform.</body>
            return text.toString();
        }
    }
}

import flash.text.TextLineMetrics;

class LineMetricsReader {
    private var metrics:TextLineMetrics;

    public function LineMetricsReader(metrics:TextLineMetrics) {
        this.metrics = metrics;
    }

    public function toString():String {
        return "[TextLineMetrics ascent:" + metrics.ascent
            + ", descent:" + metrics.descent
            + ", leading:" + metrics.leading
            + ", width:" + metrics.width
            + ", height:" + metrics.height
            + ", x:" + metrics.x
            + "]";
    }
}